Convert Scientific Notation to decimal equivalent

by **JCasale** » Fri, 20 Jul 2007 06:19:34 GMT

How can I detect this, I have been running some code for a few days to develop some files and ran into the situation where I am getting the following data for input:

14.95313 14.45312 0
14.95313 1.570813E-015 0
14.95313 -14.45313 0
-14.95313 -28.90625 0
-14.95313 -14.45313 0
-14.95313 1.570813E-015 0
-14.95313 14.45312 0
14.95313 -28.90625 0
0 -28.90625 0
-14.95313 28.90625 0
0 28.90625 0
14.95313 28.90625 0

And my code is skipping some lines as it checks for any erroneous data:
next if grep (/[^0-9.-]/, @data);
But that thinks the scientific notation is bad. I searched the net and didn't find anything. How can I match this specific pattern and convert it?

Thanks!
jlc

by **chas.owens** » Fri, 20 Jul 2007 06:27:05 GMT



Don't write the regex yourself, use one of the ones in
Regexp::Common*.  $RE{num}{real} is probably what you want.

 As for how to make "1e3" into 1000, just add 0:

perl -e 'my $i = "1e3"; print $i, " ", $i+0, "\n"';


*  http://www.**--****.com/ ~abigail/Regexp-Common-2.120/lib/Regexp/Common.pm

by **krahnj** » Fri, 20 Jul 2007 06:36:08 GMT



perldoc -q "How do I determine whether a scalar is a number"



John
-- 
Perl isn't a toolbox, but a small machine shop where you
can special-order certain sorts of tools at low cost and
in short order.                            -- Larry Wall

by **fxn** » Fri, 20 Jul 2007 06:38:09 GMT

El Jul 18, 2007, a las 11:19 PM, Joseph L. Casale escribi
>> How can I detect this, I have been running some code for a few days  
>> to develop some files and ran into the situation where I am getting  
>> the following data for input:
>>
>> 14.95313 14.45312 0
>> 14.95313 1.570813E-015 0
>> 14.95313 -14.45313 0
>> -14.95313 -28.90625 0
>> -14.95313 -14.45313 0
>> -14.95313 1.570813E-015 0
>> -14.95313 14.45312 0
>> 14.95313 -28.90625 0
>> 0 -28.90625 0
>> -14.95313 28.90625 0
>> 0 28.90625 0
>> 14.95313 28.90625 0
>>
>> And my code is skipping some lines as it checks for any erroneous  
>> data:
>> next if grep (/[^0-9.-]/, @data);
>> But that thinks the scientific notation is bad. I searched the net  
>> and didn't find anything. How can I match this specific pattern and  
>> convert it?

I am not sure I understand the problem to solve.

You need to filter out lines that contain something that's *not* a  
number? If that's the case, is @data a split on whitespace for each  
line? If that's the case in turn, have a look at

   perldoc -q determine

or delegate the job to Regexp::Common:

   $ perl -MRegexp::Common -wle 'print 1 if "1.570813E-015" =~ /\A$RE 
{num}{real}\z/'
   1

-- fxn

by **chas.owens** » Fri, 20 Jul 2007 07:20:05 GMT





It is important to note that the print function* will use scientific
notation on numbers that are very large or very small.  For instance
0.000000000000001570813 will be printed as "1.570813e-15".  If you
absolutely must have 0.000000000000001570813 then you will need to use
printf or sprintf:

#!/usr/bin/perl

use strict;
use warnings;

my @n = (
        0.000000000000001570813,
        10000000000000000000000,
        "1e4",
        "1e-4"
);

for my $n (@n) {
        my $s = expand($n);
        print "$n is $s\n";
}

sub expand {
        my $n = shift;
        return $n unless $n =~ /^(.*)e([-+]?)(.*)$/;
        my ($num, $sign, $exp) = ($1, $2, $3);
        my $sig = $sign eq '-' ? "." . ($exp - 1 + length $num) : '';
        return sprintf "%${sig}f", $n;
}


* actually any conversion of a number to string for very large or
small numbers, that is why the unless in expand works.

by **chas.owens** » Fri, 20 Jul 2007 07:31:29 GMT



Is "foo10bar" valid?  /^$RE{num}{real}$/ says no, but /$RE{num}{real}/
says yes.  \A and \z are similar to ^ and $, but are not effected by
the m and s flags (which is not an issue in your case since you are
splitting on whitespace).


Not in Perl 5 (Perl 6 will have the smart match operator ~~).  If you
want to bail if any of the values in @data are not numbers then you
should say

next if grep { not /^$RE{num}{real}$/ } @data;

Or if you want to reduce @data to just the numbers

next unless my @num = grep { /^$RE{num}{real}$/ } @data;

by **chas.owens** » Fri, 20 Jul 2007 11:23:24 GMT


snip

Sort of, the code doesn't modify the original array, it creates a new
array with only the values that are numbers.

by **fxn** » Fri, 20 Jul 2007 17:44:15 GMT

El Jul 19, 2007, a las 12:19 AM, Joseph L. Casale escribi

>> Interesting,
>> I see from your regexp you use a \A and \z, from Perldoc this means:
>> \A      Match only at beginning of string
>> \z      Match only at end of string
>>
>> I am not sure I understand this requirement?

^ and $ depend on flags, and $ allows an optional trailing newline.  
When I want to match a complete string exactly, I tend to use \A and  
\z because they convey that intention clearly.

If your code processes line by line and splits on whitespace, \A ...  
\z is equivalent to ^ ... $.

>> In my case, I am checking an array of 3 scalars. Does this make sense:
>> next unless @data =~ /$RE {num}{real}/;
>> Does the regexp know to evaluate each element in the array  
>> implicitly? Or do I need to tell it this?

Detecting whether something holds in an array is the job of grep:

   my $numbers = grep /\A$RE{num}{real}\z/, @data;
   next unless $numbers == @data;

-- fxn

by **rvtol+news** » Sun, 22 Jul 2007 15:21:50 GMT

Xavier Noria schreef:



Alternative:

  die if grep !/\A$RE{num}{real}\z/, @data; 
  my $numbers = scalar @data; 

-- 
Affijn, Ruud

"Gewoon is een tijger."

Convert Scientific Notation to decimal equivalent

Convert Scientific Notation to decimal equivalent

Jump to:

Next

Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Re: Convert Scientific Notation to decimal equivalent

Similar Threads:

Who is online